Annotation of src/sys/arch/i386/i386/locore.S, Revision 1.17
1.17 ! christos 1: /* $NetBSD: locore.S,v 1.16 2003/09/10 16:46:59 christos Exp $ */
1.1 fvdl 2:
3: /*-
4: * Copyright (c) 1998, 2000 The NetBSD Foundation, Inc.
5: * All rights reserved.
6: *
7: * This code is derived from software contributed to The NetBSD Foundation
8: * by Charles M. Hannum.
9: *
10: * Redistribution and use in source and binary forms, with or without
11: * modification, are permitted provided that the following conditions
12: * are met:
13: * 1. Redistributions of source code must retain the above copyright
14: * notice, this list of conditions and the following disclaimer.
15: * 2. Redistributions in binary form must reproduce the above copyright
16: * notice, this list of conditions and the following disclaimer in the
17: * documentation and/or other materials provided with the distribution.
18: * 3. All advertising materials mentioning features or use of this software
19: * must display the following acknowledgement:
20: * This product includes software developed by the NetBSD
21: * Foundation, Inc. and its contributors.
22: * 4. Neither the name of The NetBSD Foundation nor the names of its
23: * contributors may be used to endorse or promote products derived
24: * from this software without specific prior written permission.
25: *
26: * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
27: * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
28: * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
29: * PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
30: * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
31: * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
32: * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
33: * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
34: * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
35: * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
36: * POSSIBILITY OF SUCH DAMAGE.
37: */
38:
39: /*-
40: * Copyright (c) 1990 The Regents of the University of California.
41: * All rights reserved.
42: *
43: * This code is derived from software contributed to Berkeley by
44: * William Jolitz.
45: *
46: * Redistribution and use in source and binary forms, with or without
47: * modification, are permitted provided that the following conditions
48: * are met:
49: * 1. Redistributions of source code must retain the above copyright
50: * notice, this list of conditions and the following disclaimer.
51: * 2. Redistributions in binary form must reproduce the above copyright
52: * notice, this list of conditions and the following disclaimer in the
53: * documentation and/or other materials provided with the distribution.
1.12 agc 54: * 3. Neither the name of the University nor the names of its contributors
1.1 fvdl 55: * may be used to endorse or promote products derived from this software
56: * without specific prior written permission.
57: *
58: * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
59: * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
60: * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
61: * ARE DISCLAIMED. IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
62: * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
63: * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
64: * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
65: * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
66: * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
67: * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
68: * SUCH DAMAGE.
69: *
70: * @(#)locore.s 7.3 (Berkeley) 5/13/91
71: */
72:
73: #include "opt_cputype.h"
74: #include "opt_ddb.h"
75: #include "opt_ipkdb.h"
76: #include "opt_vm86.h"
77: #include "opt_user_ldt.h"
78: #include "opt_dummy_nops.h"
79: #include "opt_compat_oldboot.h"
80: #include "opt_multiprocessor.h"
81: #include "opt_lockdebug.h"
82: #include "opt_realmem.h"
83:
84: #include "npx.h"
85: #include "assym.h"
86: #include "apm.h"
87: #include "lapic.h"
88: #include "ioapic.h"
1.8 fvdl 89: #include "ksyms.h"
1.1 fvdl 90:
91: #include <sys/errno.h>
92: #include <sys/syscall.h>
93:
94: #include <machine/cputypes.h>
95: #include <machine/param.h>
96: #include <machine/pte.h>
97: #include <machine/segments.h>
98: #include <machine/specialreg.h>
99: #include <machine/trap.h>
100: #include <machine/bootinfo.h>
101:
102: #if NLAPIC > 0
103: #include <machine/i82489reg.h>
104: #endif
105:
106: /* LINTSTUB: include <sys/types.h> */
107: /* LINTSTUB: include <machine/cpu.h> */
108: /* LINTSTUB: include <sys/systm.h> */
109:
110: #include <machine/asm.h>
111:
112: #if defined(MULTIPROCESSOR)
113:
1.5 thorpej 114: #define SET_CURLWP(lwp,cpu) \
1.1 fvdl 115: movl CPUVAR(SELF),cpu ; \
1.5 thorpej 116: movl lwp,CPUVAR(CURLWP) ; \
117: movl cpu,L_CPU(lwp)
1.1 fvdl 118:
119: #else
120:
1.5 thorpej 121: #define SET_CURLWP(lwp,tcpu) movl lwp,CPUVAR(CURLWP)
122: #define GET_CURLWP(reg) movl CPUVAR(CURLWP),reg
1.1 fvdl 123:
124: #endif
125:
126: #define GET_CURPCB(reg) movl CPUVAR(CURPCB),reg
127: #define SET_CURPCB(reg) movl reg,CPUVAR(CURPCB)
128:
129: #define CLEAR_RESCHED(reg) movl reg,CPUVAR(RESCHED)
130:
131: /* XXX temporary kluge; these should not be here */
132: /* Get definitions for IOM_BEGIN, IOM_END, and IOM_SIZE */
133: #include <dev/isa/isareg.h>
134:
135:
136: /* Disallow old names for REALBASEMEM */
137: #ifdef BIOSBASEMEM
138: #error BIOSBASEMEM option deprecated; use REALBASEMEM only if memory size reported by latest boot block is incorrect
139: #endif
140:
141: /* Disallow old names for REALEXTMEM */
142: #ifdef EXTMEM_SIZE
143: #error EXTMEM_SIZE option deprecated; use REALEXTMEM only if memory size reported by latest boot block is incorrect
144: #endif
145: #ifdef BIOSEXTMEM
146: #error BIOSEXTMEM option deprecated; use REALEXTMEM only if memory size reported by latest boot block is incorrect
147: #endif
148:
149: #include <machine/frameasm.h>
150:
151:
152: #ifdef MULTIPROCESSOR
153: #include <machine/i82489reg.h>
154: #endif
155:
156: /*
157: * PTmap is recursive pagemap at top of virtual address space.
158: * Within PTmap, the page directory can be found (third indirection).
159: *
160: * XXX 4 == sizeof pde
161: */
162: .set _C_LABEL(PTmap),(PDSLOT_PTE << PDSHIFT)
1.7 thorpej 163: .set _C_LABEL(PTD),(_C_LABEL(PTmap) + PDSLOT_PTE * PAGE_SIZE)
1.1 fvdl 164: .set _C_LABEL(PTDpde),(_C_LABEL(PTD) + PDSLOT_PTE * 4)
165:
166: /*
167: * APTmap, APTD is the alternate recursive pagemap.
168: * It's used when modifying another process's page tables.
169: *
170: * XXX 4 == sizeof pde
171: */
172: .set _C_LABEL(APTmap),(PDSLOT_APTE << PDSHIFT)
1.7 thorpej 173: .set _C_LABEL(APTD),(_C_LABEL(APTmap) + PDSLOT_APTE * PAGE_SIZE)
1.1 fvdl 174: .set _C_LABEL(APTDpde),(_C_LABEL(PTD) + PDSLOT_APTE * 4)
175:
176:
177: /*
178: * Initialization
179: */
180: .data
181:
182: .globl _C_LABEL(cpu)
183: .globl _C_LABEL(esym),_C_LABEL(boothowto)
184: .globl _C_LABEL(bootinfo),_C_LABEL(atdevbase)
185: #ifdef COMPAT_OLDBOOT
186: .globl _C_LABEL(bootdev)
187: #endif
188: .globl _C_LABEL(proc0paddr),_C_LABEL(PTDpaddr)
189: .globl _C_LABEL(biosbasemem),_C_LABEL(biosextmem)
190: .globl _C_LABEL(gdt)
191: #ifdef I586_CPU
192: .globl _C_LABEL(idt)
193: #endif
194: .globl _C_LABEL(lapic_tpr)
195:
196: #if NLAPIC > 0
197: #ifdef __ELF__
1.7 thorpej 198: .align PAGE_SIZE
1.1 fvdl 199: #else
200: .align 12
201: #endif
202: .globl _C_LABEL(local_apic), _C_LABEL(lapic_id)
203: _C_LABEL(local_apic):
204: .space LAPIC_ID
205: _C_LABEL(lapic_id):
206: .long 0x00000000
207: .space LAPIC_TPRI-(LAPIC_ID+4)
208: _C_LABEL(lapic_tpr):
209: .space LAPIC_PPRI-LAPIC_TPRI
210: _C_LABEL(lapic_ppr):
211: .space LAPIC_ISR-LAPIC_PPRI
212: _C_LABEL(lapic_isr):
1.7 thorpej 213: .space PAGE_SIZE-LAPIC_ISR
1.1 fvdl 214: #else
215: _C_LABEL(lapic_tpr):
216: .long 0
217: #endif
218:
219:
220: _C_LABEL(cpu): .long 0 # are we 386, 386sx, or 486,
221: # or Pentium, or..
222: _C_LABEL(esym): .long 0 # ptr to end of syms
223: _C_LABEL(atdevbase): .long 0 # location of start of iomem in virtual
224: _C_LABEL(proc0paddr): .long 0
225: _C_LABEL(PTDpaddr): .long 0 # paddr of PTD, for libkvm
226: #ifndef REALBASEMEM
227: _C_LABEL(biosbasemem): .long 0 # base memory reported by BIOS
228: #else
229: _C_LABEL(biosbasemem): .long REALBASEMEM
230: #endif
231: #ifndef REALEXTMEM
232: _C_LABEL(biosextmem): .long 0 # extended memory reported by BIOS
233: #else
234: _C_LABEL(biosextmem): .long REALEXTMEM
235: #endif
236:
237: .space 512
238: tmpstk:
239:
240:
1.13 christos 241: #define _RELOC(x) ((x) - KERNBASE_LOCORE)
1.1 fvdl 242: #define RELOC(x) _RELOC(_C_LABEL(x))
243:
244: .text
245: .globl _C_LABEL(kernel_text)
246: .set _C_LABEL(kernel_text),KERNTEXTOFF
247:
248: .globl start
249: start: movw $0x1234,0x472 # warm boot
250:
251: /*
252: * Load parameters from stack
253: * (howto, [bootdev], bootinfo, esym, basemem, extmem).
254: */
255: movl 4(%esp),%eax
256: movl %eax,RELOC(boothowto)
257: #ifdef COMPAT_OLDBOOT
258: movl 8(%esp),%eax
259: movl %eax,RELOC(bootdev)
260: #endif
261: movl 12(%esp),%eax
262:
263: testl %eax, %eax
264: jz 1f
265: movl (%eax), %ebx /* number of entries */
266: movl $RELOC(bootinfo), %edi
267: movl %ebx, (%edi)
268: addl $4, %edi
269: 2:
270: testl %ebx, %ebx
271: jz 1f
272: addl $4, %eax
273: movl (%eax), %ecx /* address of entry */
274: pushl %eax
275: pushl (%ecx) /* len */
276: pushl %ecx
277: pushl %edi
278: addl (%ecx), %edi /* update dest pointer */
279: cmpl $_RELOC(_C_LABEL(bootinfo) + BOOTINFO_MAXSIZE), %edi
280: jg 2f
281: call _C_LABEL(memcpy)
282: addl $12, %esp
283: popl %eax
284: subl $1, %ebx
285: jmp 2b
286: 2: /* cleanup for overflow case */
287: addl $16, %esp
288: movl $RELOC(bootinfo), %edi
289: subl %ebx, (%edi) /* correct number of entries */
290: 1:
291:
292: movl 16(%esp),%eax
293: testl %eax,%eax
294: jz 1f
1.13 christos 295: addl $KERNBASE_LOCORE,%eax
1.1 fvdl 296: 1: movl %eax,RELOC(esym)
297:
298: movl RELOC(biosextmem),%eax
299: testl %eax,%eax
300: jnz 1f
301: movl 20(%esp),%eax
302: movl %eax,RELOC(biosextmem)
303: 1:
304: movl RELOC(biosbasemem),%eax
305: testl %eax,%eax
306: jnz 1f
307: movl 24(%esp),%eax
308: movl %eax,RELOC(biosbasemem)
309: 1:
310:
311: /* First, reset the PSL. */
312: pushl $PSL_MBO
313: popfl
314:
315: /* Clear segment registers; always null in proc0. */
316: xorl %eax,%eax
317: movw %ax,%fs
318: movw %ax,%gs
319: decl %eax
320: movl %eax,RELOC(cpu_info_primary)+CPU_INFO_LEVEL
321:
322: /* Find out our CPU type. */
323:
324: try386: /* Try to toggle alignment check flag; does not exist on 386. */
325: pushfl
326: popl %eax
327: movl %eax,%ecx
328: orl $PSL_AC,%eax
329: pushl %eax
330: popfl
331: pushfl
332: popl %eax
333: xorl %ecx,%eax
334: andl $PSL_AC,%eax
335: pushl %ecx
336: popfl
337:
338: testl %eax,%eax
339: jnz try486
340:
341: /*
342: * Try the test of a NexGen CPU -- ZF will not change on a DIV
343: * instruction on a NexGen, it will on an i386. Documented in
344: * Nx586 Processor Recognition Application Note, NexGen, Inc.
345: */
346: movl $0x5555,%eax
347: xorl %edx,%edx
348: movl $2,%ecx
349: divl %ecx
350: jnz is386
351:
352: isnx586:
353: /*
354: * Don't try cpuid, as Nx586s reportedly don't support the
355: * PSL_ID bit.
356: */
357: movl $CPU_NX586,RELOC(cpu)
358: jmp 2f
359:
360: is386:
361: movl $CPU_386,RELOC(cpu)
362: jmp 2f
363:
364: try486: /* Try to toggle identification flag; does not exist on early 486s. */
365: pushfl
366: popl %eax
367: movl %eax,%ecx
368: xorl $PSL_ID,%eax
369: pushl %eax
370: popfl
371: pushfl
372: popl %eax
373: xorl %ecx,%eax
374: andl $PSL_ID,%eax
375: pushl %ecx
376: popfl
377:
378: testl %eax,%eax
379: jnz try586
380: is486: movl $CPU_486,RELOC(cpu)
381: /*
382: * Check Cyrix CPU
383: * Cyrix CPUs do not change the undefined flags following
384: * execution of the divide instruction which divides 5 by 2.
385: *
386: * Note: CPUID is enabled on M2, so it passes another way.
387: */
388: pushfl
389: movl $0x5555, %eax
390: xorl %edx, %edx
391: movl $2, %ecx
392: clc
393: divl %ecx
394: jnc trycyrix486
395: popfl
396: jmp 2f
397: trycyrix486:
398: movl $CPU_6x86,RELOC(cpu) # set CPU type
399: /*
400: * Check for Cyrix 486 CPU by seeing if the flags change during a
401: * divide. This is documented in the Cx486SLC/e SMM Programmer's
402: * Guide.
403: */
404: xorl %edx,%edx
405: cmpl %edx,%edx # set flags to known state
406: pushfl
407: popl %ecx # store flags in ecx
408: movl $-1,%eax
409: movl $4,%ebx
410: divl %ebx # do a long division
411: pushfl
412: popl %eax
413: xorl %ecx,%eax # are the flags different?
414: testl $0x8d5,%eax # only check C|PF|AF|Z|N|V
415: jne 2f # yes; must be Cyrix 6x86 CPU
416: movl $CPU_486DLC,RELOC(cpu) # set CPU type
417:
418: #ifndef CYRIX_CACHE_WORKS
419: /* Disable caching of the ISA hole only. */
420: invd
421: movb $CCR0,%al # Configuration Register index (CCR0)
422: outb %al,$0x22
423: inb $0x23,%al
424: orb $(CCR0_NC1|CCR0_BARB),%al
425: movb %al,%ah
426: movb $CCR0,%al
427: outb %al,$0x22
428: movb %ah,%al
429: outb %al,$0x23
430: invd
431: #else /* CYRIX_CACHE_WORKS */
432: /* Set cache parameters */
433: invd # Start with guaranteed clean cache
434: movb $CCR0,%al # Configuration Register index (CCR0)
435: outb %al,$0x22
436: inb $0x23,%al
437: andb $~CCR0_NC0,%al
438: #ifndef CYRIX_CACHE_REALLY_WORKS
439: orb $(CCR0_NC1|CCR0_BARB),%al
440: #else
441: orb $CCR0_NC1,%al
442: #endif
443: movb %al,%ah
444: movb $CCR0,%al
445: outb %al,$0x22
446: movb %ah,%al
447: outb %al,$0x23
448: /* clear non-cacheable region 1 */
449: movb $(NCR1+2),%al
450: outb %al,$0x22
451: movb $NCR_SIZE_0K,%al
452: outb %al,$0x23
453: /* clear non-cacheable region 2 */
454: movb $(NCR2+2),%al
455: outb %al,$0x22
456: movb $NCR_SIZE_0K,%al
457: outb %al,$0x23
458: /* clear non-cacheable region 3 */
459: movb $(NCR3+2),%al
460: outb %al,$0x22
461: movb $NCR_SIZE_0K,%al
462: outb %al,$0x23
463: /* clear non-cacheable region 4 */
464: movb $(NCR4+2),%al
465: outb %al,$0x22
466: movb $NCR_SIZE_0K,%al
467: outb %al,$0x23
468: /* enable caching in CR0 */
469: movl %cr0,%eax
470: andl $~(CR0_CD|CR0_NW),%eax
471: movl %eax,%cr0
472: invd
473: #endif /* CYRIX_CACHE_WORKS */
474:
475: jmp 2f
476:
477: try586: /* Use the `cpuid' instruction. */
478: xorl %eax,%eax
479: cpuid
480: movl %eax,RELOC(cpu_info_primary)+CPU_INFO_LEVEL
481:
482: 2:
483: /*
484: * Finished with old stack; load new %esp now instead of later so we
485: * can trace this code without having to worry about the trace trap
486: * clobbering the memory test or the zeroing of the bss+bootstrap page
487: * tables.
488: *
489: * The boot program should check:
490: * text+data <= &stack_variable - more_space_for_stack
491: * text+data+bss+pad+space_for_page_tables <= end_of_memory
492: * Oops, the gdt is in the carcass of the boot program so clearing
493: * the rest of memory is still not possible.
494: */
495: movl $_RELOC(tmpstk),%esp # bootstrap stack end location
496:
497: /*
498: * Virtual address space of kernel:
499: *
500: * text | data | bss | [syms] | page dir | proc0 kstack
501: * 0 1 2 3
502: */
1.7 thorpej 503: #define PROC0PDIR ((0) * PAGE_SIZE)
504: #define PROC0STACK ((1) * PAGE_SIZE)
505: #define SYSMAP ((1+UPAGES) * PAGE_SIZE)
506: #define TABLESIZE ((1+UPAGES) * PAGE_SIZE) /* + nkpde * PAGE_SIZE */
1.1 fvdl 507:
508: /* Find end of kernel image. */
509: movl $RELOC(end),%edi
1.8 fvdl 510: #if (NKSYMS || defined(DDB) || defined(LKM)) && !defined(SYMTAB_SPACE)
1.1 fvdl 511: /* Save the symbols (if loaded). */
512: movl RELOC(esym),%eax
513: testl %eax,%eax
514: jz 1f
1.13 christos 515: subl $KERNBASE_LOCORE,%eax
1.1 fvdl 516: movl %eax,%edi
517: 1:
518: #endif
519:
520: /* Calculate where to start the bootstrap tables. */
521: movl %edi,%esi # edi = esym ? esym : end
522: addl $PGOFSET,%esi # page align up
523: andl $~PGOFSET,%esi
524:
525: /*
526: * Calculate the size of the kernel page table directory, and
527: * how many entries it will have.
528: */
529: movl RELOC(nkpde),%ecx # get nkpde
530: cmpl $NKPTP_MIN,%ecx # larger than min?
531: jge 1f
532: movl $NKPTP_MIN,%ecx # set at min
533: jmp 2f
534: 1: cmpl $NKPTP_MAX,%ecx # larger than max?
535: jle 2f
536: movl $NKPTP_MAX,%ecx
537: 2:
538:
539: /* Clear memory for bootstrap tables. */
540: shll $PGSHIFT,%ecx
541: addl $TABLESIZE,%ecx
542: addl %esi,%ecx # end of tables
543: subl %edi,%ecx # size of tables
544: shrl $2,%ecx
545: xorl %eax,%eax
546: cld
547: rep
548: stosl
549:
550: /*
551: * fillkpt
552: * eax = pte (page frame | control | status)
553: * ebx = page table address
554: * ecx = number of pages to map
555: */
556: #define fillkpt \
557: 1: movl %eax,(%ebx) ; \
1.7 thorpej 558: addl $PAGE_SIZE,%eax ; /* increment physical address */ \
1.1 fvdl 559: addl $4,%ebx ; /* next pte */ \
560: loop 1b ;
561:
562: /*
563: * Build initial page tables.
564: */
565: /* Calculate end of text segment, rounded to a page. */
566: leal (RELOC(etext)+PGOFSET),%edx
567: andl $~PGOFSET,%edx
568:
569: /* Skip over the first 1MB. */
570: movl $_RELOC(KERNTEXTOFF),%eax
571: movl %eax,%ecx
572: shrl $PGSHIFT,%ecx
573: leal (SYSMAP)(%esi,%ecx,4),%ebx
574:
575: /* Map the kernel text read-only. */
576: movl %edx,%ecx
577: subl %eax,%ecx
578: shrl $PGSHIFT,%ecx
579: orl $(PG_V|PG_KR),%eax
580: fillkpt
581:
582: /* Map the data, BSS, and bootstrap tables read-write. */
583: leal (PG_V|PG_KW)(%edx),%eax
584: movl RELOC(nkpde),%ecx
585: shll $PGSHIFT,%ecx
586: addl $TABLESIZE,%ecx
587: addl %esi,%ecx # end of tables
588: subl %edx,%ecx # subtract end of text
589: shrl $PGSHIFT,%ecx
590: fillkpt
591:
592: /* Map ISA I/O memory. */
593: movl $(IOM_BEGIN|PG_V|PG_KW/*|PG_N*/),%eax # having these bits set
594: movl $(IOM_SIZE>>PGSHIFT),%ecx # for this many pte s,
595: fillkpt
596:
597: /*
598: * Construct a page table directory.
599: */
600: /* Install PDEs for temporary double map of kernel. */
601: movl RELOC(nkpde),%ecx # for this many pde s,
602: leal (PROC0PDIR+0*4)(%esi),%ebx # which is where temp maps!
603: leal (SYSMAP+PG_V|PG_KW)(%esi),%eax # pte for KPT in proc 0,
604: fillkpt
605:
606: /* Map kernel PDEs. */
607: movl RELOC(nkpde),%ecx # for this many pde s,
608: leal (PROC0PDIR+PDSLOT_KERN*4)(%esi),%ebx # kernel pde offset
609: leal (SYSMAP+PG_V|PG_KW)(%esi),%eax # pte for KPT in proc 0,
610: fillkpt
611:
612: /* Install a PDE recursively mapping page directory as a page table! */
613: leal (PROC0PDIR+PG_V|PG_KW)(%esi),%eax # pte for ptd
614: movl %eax,(PROC0PDIR+PDSLOT_PTE*4)(%esi) # recursive PD slot
615:
616: /* Save phys. addr of PTD, for libkvm. */
617: movl %esi,RELOC(PTDpaddr)
618:
619: /* Load base of page directory and enable mapping. */
620: movl %esi,%eax # phys address of ptd in proc 0
621: movl %eax,%cr3 # load ptd addr into mmu
622: movl %cr0,%eax # get control word
623: # enable paging & NPX emulation
624: orl $(CR0_PE|CR0_PG|CR0_NE|CR0_TS|CR0_EM|CR0_MP),%eax
625: movl %eax,%cr0 # and let's page NOW!
626:
627: pushl $begin # jump to high mem
628: ret
629:
630: begin:
1.13 christos 631: /* Now running relocated at KERNBASE_LOCORE. Remove double mapping. */
1.1 fvdl 632: movl _C_LABEL(nkpde),%ecx # for this many pde s,
633: leal (PROC0PDIR+0*4)(%esi),%ebx # which is where temp maps!
1.13 christos 634: addl $(KERNBASE_LOCORE), %ebx # now use relocated address
1.1 fvdl 635: 1: movl $0,(%ebx)
636: addl $4,%ebx # next pde
637: loop 1b
638:
639: /* Relocate atdevbase. */
640: movl _C_LABEL(nkpde),%edx
641: shll $PGSHIFT,%edx
1.13 christos 642: addl $(TABLESIZE+KERNBASE_LOCORE),%edx
1.1 fvdl 643: addl %esi,%edx
644: movl %edx,_C_LABEL(atdevbase)
645:
646: /* Set up bootstrap stack. */
1.13 christos 647: leal (PROC0STACK+KERNBASE_LOCORE)(%esi),%eax
1.1 fvdl 648: movl %eax,_C_LABEL(proc0paddr)
649: leal (USPACE-FRAMESIZE)(%eax),%esp
650: movl %esi,PCB_CR3(%eax) # pcb->pcb_cr3
651: xorl %ebp,%ebp # mark end of frames
652:
653: subl $NGDT*8, %esp # space for temporary gdt
654: pushl %esp
655: call _C_LABEL(initgdt)
656: addl $4,%esp
657:
658: movl _C_LABEL(nkpde),%eax
659: shll $PGSHIFT,%eax
660: addl $TABLESIZE,%eax
661: addl %esi,%eax # skip past stack and page tables
662:
663: pushl %eax
664: call _C_LABEL(init386) # wire 386 chip for unix operation
665: addl $4+NGDT*8,%esp # pop temporary gdt
666:
667: #ifdef SAFARI_FIFO_HACK
668: movb $5,%al
669: movw $0x37b,%dx
670: outb %al,%dx
671: movw $0x37f,%dx
672: inb %dx,%al
673: movb %al,%cl
674:
675: orb $1,%cl
676:
677: movb $5,%al
678: movw $0x37b,%dx
679: outb %al,%dx
680: movw $0x37f,%dx
681: movb %cl,%al
682: outb %al,%dx
683: #endif /* SAFARI_FIFO_HACK */
684:
685: call _C_LABEL(main)
686:
687: /*
688: * void proc_trampoline(void);
689: * This is a trampoline function pushed onto the stack of a newly created
690: * process in order to do some additional setup. The trampoline is entered by
691: * cpu_switch()ing to the process, so we abuse the callee-saved registers used
692: * by cpu_switch() to store the information about the stub to call.
693: * NOTE: This function does not have a normal calling sequence!
694: */
695: /* LINTSTUB: Func: void proc_trampoline(void) */
696: NENTRY(proc_trampoline)
697: #ifdef MULTIPROCESSOR
698: call _C_LABEL(proc_trampoline_mp)
699: #endif
700: movl $IPL_NONE,CPUVAR(ILEVEL)
701: pushl %ebx
702: call *%esi
703: addl $4,%esp
704: INTRFASTEXIT
705: /* NOTREACHED */
706:
707: /*****************************************************************************/
1.16 christos 708: #ifdef COMPAT_16
1.1 fvdl 709: /*
710: * Signal trampoline; copied to top of user stack.
711: */
712: /* LINTSTUB: Var: char sigcode[1], esigcode[1]; */
713: NENTRY(sigcode)
714: /*
715: * Handler has returned here as if we called it. The sigcontext
716: * is on the stack after the 3 args "we" pushed.
717: */
718: leal 12(%esp),%eax # get pointer to sigcontext
719: movl %eax,4(%esp) # put it in the argument slot
720: # fake return address already there
1.17 ! christos 721: movl $SYS_compat_16___sigreturn14,%eax
1.1 fvdl 722: int $0x80 # enter kernel with args on stack
723: movl $SYS_exit,%eax
724: int $0x80 # exit if sigreturn fails
725: .globl _C_LABEL(esigcode)
726: _C_LABEL(esigcode):
1.16 christos 727: #endif
1.1 fvdl 728:
729: /*****************************************************************************/
730:
731: /*
732: * The following primitives are used to fill and copy regions of memory.
733: */
734:
735: /*
736: * XXX No section 9 man page for fillw.
737: * fillw seems to be very sparsely used (only in pccons it seems.)
738: * One wonders if it couldn't be done without.
739: * -- Perry Metzger, May 7, 2001
740: */
741: /*
742: * void fillw(short pattern, void *addr, size_t len);
743: * Write len copies of pattern at addr.
744: */
745: /* LINTSTUB: Func: void fillw(short pattern, void *addr, size_t len) */
746: ENTRY(fillw)
747: pushl %edi
748: movl 8(%esp),%eax
749: movl 12(%esp),%edi
750: movw %ax,%cx
751: rorl $16,%eax
752: movw %cx,%ax
753: cld
754: movl 16(%esp),%ecx
755: shrl %ecx # do longwords
756: rep
757: stosl
758: movl 16(%esp),%ecx
759: andl $1,%ecx # do remainder
760: rep
761: stosw
762: popl %edi
763: ret
764:
765: /*
766: * int kcopy(const void *from, void *to, size_t len);
767: * Copy len bytes, abort on fault.
768: */
769: /* LINTSTUB: Func: int kcopy(const void *from, void *to, size_t len) */
770: ENTRY(kcopy)
771: pushl %esi
772: pushl %edi
773: GET_CURPCB(%eax) # load curpcb into eax and set on-fault
774: pushl PCB_ONFAULT(%eax)
775: movl $_C_LABEL(copy_fault), PCB_ONFAULT(%eax)
776:
777: movl 16(%esp),%esi
778: movl 20(%esp),%edi
779: movl 24(%esp),%ecx
780: movl %edi,%eax
781: subl %esi,%eax
782: cmpl %ecx,%eax # overlapping?
783: jb 1f
784: cld # nope, copy forward
785: shrl $2,%ecx # copy by 32-bit words
786: rep
787: movsl
788: movl 24(%esp),%ecx
789: andl $3,%ecx # any bytes left?
790: rep
791: movsb
792:
793: GET_CURPCB(%edx) # XXX save curpcb?
794: popl PCB_ONFAULT(%edx)
795: popl %edi
796: popl %esi
797: xorl %eax,%eax
798: ret
799:
800: ALIGN_TEXT
801: 1: addl %ecx,%edi # copy backward
802: addl %ecx,%esi
803: std
804: andl $3,%ecx # any fractional bytes?
805: decl %edi
806: decl %esi
807: rep
808: movsb
809: movl 24(%esp),%ecx # copy remainder by 32-bit words
810: shrl $2,%ecx
811: subl $3,%esi
812: subl $3,%edi
813: rep
814: movsl
815: cld
816:
817: GET_CURPCB(%edx)
818: popl PCB_ONFAULT(%edx)
819: popl %edi
820: popl %esi
821: xorl %eax,%eax
822: ret
823:
824: /*****************************************************************************/
825:
826: /*
827: * The following primitives are used to copy data in and out of the user's
828: * address space.
829: */
830:
831: /*
832: * Default to the lowest-common-denominator. We will improve it
833: * later.
834: */
835: #if defined(I386_CPU)
836: #define DEFAULT_COPYOUT _C_LABEL(i386_copyout)
837: #define DEFAULT_COPYIN _C_LABEL(i386_copyin)
838: #elif defined(I486_CPU)
839: #define DEFAULT_COPYOUT _C_LABEL(i486_copyout)
840: #define DEFAULT_COPYIN _C_LABEL(i386_copyin)
841: #elif defined(I586_CPU)
842: #define DEFAULT_COPYOUT _C_LABEL(i486_copyout) /* XXX */
843: #define DEFAULT_COPYIN _C_LABEL(i386_copyin) /* XXX */
844: #elif defined(I686_CPU)
845: #define DEFAULT_COPYOUT _C_LABEL(i486_copyout) /* XXX */
846: #define DEFAULT_COPYIN _C_LABEL(i386_copyin) /* XXX */
847: #endif
848:
849: .data
850:
851: .globl _C_LABEL(copyout_func)
852: _C_LABEL(copyout_func):
853: .long DEFAULT_COPYOUT
854:
855: .globl _C_LABEL(copyin_func)
856: _C_LABEL(copyin_func):
857: .long DEFAULT_COPYIN
858:
859: .text
860:
861: /*
862: * int copyout(const void *from, void *to, size_t len);
863: * Copy len bytes into the user's address space.
864: * see copyout(9)
865: */
866: /* LINTSTUB: Func: int copyout(const void *kaddr, void *uaddr, size_t len) */
867: ENTRY(copyout)
868: jmp *_C_LABEL(copyout_func)
869:
870: #if defined(I386_CPU)
871: /* LINTSTUB: Func: int i386_copyout(const void *kaddr, void *uaddr, size_t len) */
872: ENTRY(i386_copyout)
873: pushl %esi
874: pushl %edi
875: pushl $0
876:
877: movl 16(%esp),%esi
878: movl 20(%esp),%edi
879: movl 24(%esp),%eax
880:
881: /*
882: * We check that the end of the destination buffer is not past the end
883: * of the user's address space. If it's not, then we only need to
884: * check that each page is writable. The 486 will do this for us; the
885: * 386 will not. (We assume that pages in user space that are not
886: * writable by the user are not writable by the kernel either.)
887: */
888: movl %edi,%edx
889: addl %eax,%edx
890: jc _C_LABEL(copy_efault)
891: cmpl $VM_MAXUSER_ADDRESS,%edx
892: ja _C_LABEL(copy_efault)
893:
894: testl %eax,%eax # anything to do?
895: jz 3f
896:
897: /*
898: * We have to check each PTE for (write) permission, since the CPU
899: * doesn't do it for us.
900: */
901:
902: /* Compute number of pages. */
903: movl %edi,%ecx
904: andl $PGOFSET,%ecx
905: addl %eax,%ecx
906: decl %ecx
907: shrl $PGSHIFT,%ecx
908:
909: /* Compute PTE offset for start address. */
910: shrl $PGSHIFT,%edi
911:
912: GET_CURPCB(%edx)
913: movl $2f,PCB_ONFAULT(%edx)
914:
915: 1: /* Check PTE for each page. */
916: testb $PG_RW,_C_LABEL(PTmap)(,%edi,4)
917: jz 2f
918:
919: 4: incl %edi
920: decl %ecx
921: jns 1b
922:
923: movl 20(%esp),%edi
924: movl 24(%esp),%eax
925: jmp 3f
926:
927: 2: /* Simulate a trap. */
928: pushl %ecx
929: movl %edi,%eax
930: shll $PGSHIFT,%eax
931: pushl %eax
932: call _C_LABEL(trapwrite) # trapwrite(addr)
933: addl $4,%esp # pop argument
934: popl %ecx
935: testl %eax,%eax # if not ok, return EFAULT
936: jz 4b
937: jmp _C_LABEL(copy_efault)
938:
939: 3: GET_CURPCB(%edx)
940: movl $_C_LABEL(copy_fault),PCB_ONFAULT(%edx)
941:
942: /* bcopy(%esi, %edi, %eax); */
943: cld
944: movl %eax,%ecx
945: shrl $2,%ecx
946: rep
947: movsl
948: movl %eax,%ecx
949: andl $3,%ecx
950: rep
951: movsb
952:
953: popl PCB_ONFAULT(%edx)
954: popl %edi
955: popl %esi
956: xorl %eax,%eax
957: ret
958: #endif /* I386_CPU */
959:
960: #if defined(I486_CPU) || defined(I586_CPU) || defined(I686_CPU)
961: /* LINTSTUB: Func: int i486_copyout(const void *kaddr, void *uaddr, size_t len) */
962: ENTRY(i486_copyout)
963: pushl %esi
964: pushl %edi
965: pushl $0
966:
967: movl 16(%esp),%esi
968: movl 20(%esp),%edi
969: movl 24(%esp),%eax
970:
971: /*
972: * We check that the end of the destination buffer is not past the end
973: * of the user's address space.
974: */
975: movl %edi,%edx
976: addl %eax,%edx
977: jc _C_LABEL(copy_efault)
978: cmpl $VM_MAXUSER_ADDRESS,%edx
979: ja _C_LABEL(copy_efault)
980:
981: GET_CURPCB(%edx)
982: movl $_C_LABEL(copy_fault),PCB_ONFAULT(%edx)
983:
984: /* bcopy(%esi, %edi, %eax); */
985: cld
986: movl %eax,%ecx
987: shrl $2,%ecx
988: rep
989: movsl
990: movl %eax,%ecx
991: andl $3,%ecx
992: rep
993: movsb
994:
995: popl PCB_ONFAULT(%edx)
996: popl %edi
997: popl %esi
998: xorl %eax,%eax
999: ret
1000: #endif /* I486_CPU || I586_CPU || I686_CPU */
1001:
1002: /*
1003: * int copyin(const void *from, void *to, size_t len);
1004: * Copy len bytes from the user's address space.
1005: * see copyin(9)
1006: */
1007: /* LINTSTUB: Func: int copyin(const void *uaddr, void *kaddr, size_t len) */
1008: ENTRY(copyin)
1009: jmp *_C_LABEL(copyin_func)
1010:
1011: #if defined(I386_CPU) || defined(I486_CPU) || defined(I586_CPU) || \
1012: defined(I686_CPU)
1013: /* LINTSTUB: Func: int i386_copyin(const void *uaddr, void *kaddr, size_t len) */
1014: ENTRY(i386_copyin)
1015: pushl %esi
1016: pushl %edi
1017: GET_CURPCB(%eax)
1018: pushl $0
1019: movl $_C_LABEL(copy_fault),PCB_ONFAULT(%eax)
1020:
1021: movl 16(%esp),%esi
1022: movl 20(%esp),%edi
1023: movl 24(%esp),%eax
1024:
1025: /*
1026: * We check that the end of the destination buffer is not past the end
1027: * of the user's address space. If it's not, then we only need to
1028: * check that each page is readable, and the CPU will do that for us.
1029: */
1030: movl %esi,%edx
1031: addl %eax,%edx
1032: jc _C_LABEL(copy_efault)
1033: cmpl $VM_MAXUSER_ADDRESS,%edx
1034: ja _C_LABEL(copy_efault)
1035:
1036: /* bcopy(%esi, %edi, %eax); */
1037: cld
1038: movl %eax,%ecx
1039: shrl $2,%ecx
1040: rep
1041: movsl
1042: movl %eax,%ecx
1043: andl $3,%ecx
1044: rep
1045: movsb
1046:
1047: GET_CURPCB(%edx)
1048: popl PCB_ONFAULT(%edx)
1049: popl %edi
1050: popl %esi
1051: xorl %eax,%eax
1052: ret
1053: #endif /* I386_CPU || I486_CPU || I586_CPU || I686_CPU */
1054:
1055: /* LINTSTUB: Ignore */
1056: NENTRY(copy_efault)
1057: movl $EFAULT,%eax
1058:
1059: /* LINTSTUB: Ignore */
1060: NENTRY(copy_fault)
1061: GET_CURPCB(%edx)
1062: popl PCB_ONFAULT(%edx)
1063: popl %edi
1064: popl %esi
1065: ret
1066:
1067: /*
1068: * int copyoutstr(const void *from, void *to, size_t maxlen, size_t *lencopied);
1069: * Copy a NUL-terminated string, at most maxlen characters long, into the
1070: * user's address space. Return the number of characters copied (including the
1071: * NUL) in *lencopied. If the string is too long, return ENAMETOOLONG; else
1072: * return 0 or EFAULT.
1073: * see copyoutstr(9)
1074: */
1075: /* LINTSTUB: Func: int copyoutstr(const void *kaddr, void *uaddr, size_t len, size_t *done) */
1076: ENTRY(copyoutstr)
1077: pushl %esi
1078: pushl %edi
1079:
1080: movl 12(%esp),%esi # esi = from
1081: movl 16(%esp),%edi # edi = to
1082: movl 20(%esp),%edx # edx = maxlen
1083:
1084: #if defined(I386_CPU)
1085: #if defined(I486_CPU) || defined(I586_CPU) || defined(I686_CPU)
1086: cmpl $CPUCLASS_386,_C_LABEL(cpu_class)
1087: jne 5f
1088: #endif /* I486_CPU || I586_CPU || I686_CPU */
1089:
1090: /* Compute number of bytes in first page. */
1091: movl %edi,%eax
1092: andl $PGOFSET,%eax
1.7 thorpej 1093: movl $PAGE_SIZE,%ecx
1094: subl %eax,%ecx # ecx = PAGE_SIZE - (src % PAGE_SIZE)
1.1 fvdl 1095:
1096: GET_CURPCB(%eax)
1097: movl $6f,PCB_ONFAULT(%eax)
1098:
1099: 1: /*
1100: * Once per page, check that we are still within the bounds of user
1101: * space, and check for a write fault.
1102: */
1103: cmpl $VM_MAXUSER_ADDRESS,%edi
1104: jae _C_LABEL(copystr_efault)
1105:
1106: /* Compute PTE offset. */
1107: movl %edi,%eax
1108: shrl $PGSHIFT,%eax # calculate pte address
1109:
1110: testb $PG_RW,_C_LABEL(PTmap)(,%eax,4)
1111: jnz 2f
1112:
1113: 6: /* Simulate a trap. */
1114: pushl %edx
1115: pushl %edi
1116: call _C_LABEL(trapwrite) # trapwrite(addr)
1117: addl $4,%esp # clear argument from stack
1118: popl %edx
1119: testl %eax,%eax
1120: jnz _C_LABEL(copystr_efault)
1121:
1122: 2: /* Copy up to end of this page. */
1123: subl %ecx,%edx # predecrement total count
1124: jnc 3f
1125: addl %edx,%ecx # ecx += (edx - ecx) = edx
1126: xorl %edx,%edx
1127:
1128: 3: decl %ecx
1129: js 4f
1130: lodsb
1131: stosb
1132: testb %al,%al
1133: jnz 3b
1134:
1135: /* Success -- 0 byte reached. */
1136: addl %ecx,%edx # add back residual for this page
1137: xorl %eax,%eax
1138: jmp copystr_return
1139:
1140: 4: /* Go to next page, if any. */
1.7 thorpej 1141: movl $PAGE_SIZE,%ecx
1.1 fvdl 1142: testl %edx,%edx
1143: jnz 1b
1144:
1145: /* edx is zero -- return ENAMETOOLONG. */
1146: movl $ENAMETOOLONG,%eax
1147: jmp copystr_return
1148: #endif /* I386_CPU */
1149:
1150: #if defined(I486_CPU) || defined(I586_CPU) || defined(I686_CPU)
1151: 5: GET_CURPCB(%eax)
1152: movl $_C_LABEL(copystr_fault),PCB_ONFAULT(%eax)
1153: /*
1154: * Get min(%edx, VM_MAXUSER_ADDRESS-%edi).
1155: */
1156: movl $VM_MAXUSER_ADDRESS,%eax
1157: subl %edi,%eax
1158: cmpl %edx,%eax
1159: jae 1f
1160: movl %eax,%edx
1161: movl %eax,20(%esp)
1162:
1163: 1: incl %edx
1164: cld
1165:
1166: 1: decl %edx
1167: jz 2f
1168: lodsb
1169: stosb
1170: testb %al,%al
1171: jnz 1b
1172:
1173: /* Success -- 0 byte reached. */
1174: decl %edx
1175: xorl %eax,%eax
1176: jmp copystr_return
1177:
1178: 2: /* edx is zero -- return EFAULT or ENAMETOOLONG. */
1179: cmpl $VM_MAXUSER_ADDRESS,%edi
1180: jae _C_LABEL(copystr_efault)
1181: movl $ENAMETOOLONG,%eax
1182: jmp copystr_return
1183: #endif /* I486_CPU || I586_CPU || I686_CPU */
1184:
1185: /*
1186: * int copyinstr(const void *from, void *to, size_t maxlen, size_t *lencopied);
1187: * Copy a NUL-terminated string, at most maxlen characters long, from the
1188: * user's address space. Return the number of characters copied (including the
1189: * NUL) in *lencopied. If the string is too long, return ENAMETOOLONG; else
1190: * return 0 or EFAULT.
1191: * see copyinstr(9)
1192: */
1193: /* LINTSTUB: Func: int copyinstr(const void *uaddr, void *kaddr, size_t len, size_t *done) */
1194: ENTRY(copyinstr)
1195: pushl %esi
1196: pushl %edi
1197: GET_CURPCB(%ecx)
1198: movl $_C_LABEL(copystr_fault),PCB_ONFAULT(%ecx)
1199:
1200: movl 12(%esp),%esi # %esi = from
1201: movl 16(%esp),%edi # %edi = to
1202: movl 20(%esp),%edx # %edx = maxlen
1203:
1204: /*
1205: * Get min(%edx, VM_MAXUSER_ADDRESS-%esi).
1206: */
1207: movl $VM_MAXUSER_ADDRESS,%eax
1208: subl %esi,%eax
1209: cmpl %edx,%eax
1210: jae 1f
1211: movl %eax,%edx
1212: movl %eax,20(%esp)
1213:
1214: 1: incl %edx
1215: cld
1216:
1217: 1: decl %edx
1218: jz 2f
1219: lodsb
1220: stosb
1221: testb %al,%al
1222: jnz 1b
1223:
1224: /* Success -- 0 byte reached. */
1225: decl %edx
1226: xorl %eax,%eax
1227: jmp copystr_return
1228:
1229: 2: /* edx is zero -- return EFAULT or ENAMETOOLONG. */
1230: cmpl $VM_MAXUSER_ADDRESS,%esi
1231: jae _C_LABEL(copystr_efault)
1232: movl $ENAMETOOLONG,%eax
1233: jmp copystr_return
1234:
1235: /* LINTSTUB: Ignore */
1236: NENTRY(copystr_efault)
1237: movl $EFAULT,%eax
1238:
1239: /* LINTSTUB: Ignore */
1240: NENTRY(copystr_fault)
1241: copystr_return:
1242: /* Set *lencopied and return %eax. */
1243: GET_CURPCB(%ecx)
1244: movl $0,PCB_ONFAULT(%ecx)
1245: movl 20(%esp),%ecx
1246: subl %edx,%ecx
1247: movl 24(%esp),%edx
1248: testl %edx,%edx
1249: jz 8f
1250: movl %ecx,(%edx)
1251:
1252: 8: popl %edi
1253: popl %esi
1254: ret
1255:
1256: /*
1257: * int copystr(const void *from, void *to, size_t maxlen, size_t *lencopied);
1258: * Copy a NUL-terminated string, at most maxlen characters long. Return the
1259: * number of characters copied (including the NUL) in *lencopied. If the
1260: * string is too long, return ENAMETOOLONG; else return 0.
1261: * see copystr(9)
1262: */
1263: /* LINTSTUB: Func: int copystr(const void *kfaddr, void *kdaddr, size_t len, size_t *done) */
1264: ENTRY(copystr)
1265: pushl %esi
1266: pushl %edi
1267:
1268: movl 12(%esp),%esi # esi = from
1269: movl 16(%esp),%edi # edi = to
1270: movl 20(%esp),%edx # edx = maxlen
1271: incl %edx
1272: cld
1273:
1274: 1: decl %edx
1275: jz 4f
1276: lodsb
1277: stosb
1278: testb %al,%al
1279: jnz 1b
1280:
1281: /* Success -- 0 byte reached. */
1282: decl %edx
1283: xorl %eax,%eax
1284: jmp 6f
1285:
1286: 4: /* edx is zero -- return ENAMETOOLONG. */
1287: movl $ENAMETOOLONG,%eax
1288:
1289: 6: /* Set *lencopied and return %eax. */
1290: movl 20(%esp),%ecx
1291: subl %edx,%ecx
1292: movl 24(%esp),%edx
1293: testl %edx,%edx
1294: jz 7f
1295: movl %ecx,(%edx)
1296:
1297: 7: popl %edi
1298: popl %esi
1299: ret
1300:
1301: /*
1302: * long fuword(const void *uaddr);
1303: * Fetch an int from the user's address space.
1304: * see fuword(9)
1305: */
1306: /* LINTSTUB: Func: long fuword(const void *base) */
1307: ENTRY(fuword)
1308: movl 4(%esp),%edx
1309: cmpl $VM_MAXUSER_ADDRESS-4,%edx
1310: ja _C_LABEL(fusuaddrfault)
1311: GET_CURPCB(%ecx)
1312: movl $_C_LABEL(fusufault),PCB_ONFAULT(%ecx)
1313: movl (%edx),%eax
1314: movl $0,PCB_ONFAULT(%ecx)
1315: ret
1316:
1317: /*
1318: * int fusword(const void *uaddr);
1319: * Fetch a short from the user's address space.
1320: * see fusword(9)
1321: */
1322: /* LINTSTUB: Func: int fusword(const void *base) */
1323: ENTRY(fusword)
1324: movl 4(%esp),%edx
1325: cmpl $VM_MAXUSER_ADDRESS-2,%edx
1326: ja _C_LABEL(fusuaddrfault)
1327: GET_CURPCB(%ecx)
1328: movl $_C_LABEL(fusufault),PCB_ONFAULT(%ecx)
1329: movzwl (%edx),%eax
1330: movl $0,PCB_ONFAULT(%ecx)
1331: ret
1332:
1333: /*
1334: * int fuswintr(const void *uaddr);
1335: * Fetch a short from the user's address space. Can be called during an
1336: * interrupt.
1337: * see fuswintr(9)
1338: */
1339: /* LINTSTUB: Func: int fuswintr(const void *base) */
1340: ENTRY(fuswintr)
1341: movl 4(%esp),%edx
1342: cmpl $VM_MAXUSER_ADDRESS-2,%edx
1343: ja _C_LABEL(fusuaddrfault)
1.5 thorpej 1344: movl CPUVAR(CURLWP),%ecx
1345: movl L_ADDR(%ecx),%ecx
1.1 fvdl 1346: movl $_C_LABEL(fusubail),PCB_ONFAULT(%ecx)
1347: movzwl (%edx),%eax
1348: movl $0,PCB_ONFAULT(%ecx)
1349: ret
1350:
1351: /*
1352: * int fubyte(const void *uaddr);
1353: * Fetch a byte from the user's address space.
1354: * see fubyte(9)
1355: */
1356: /* LINTSTUB: Func: int fubyte(const void *base) */
1357: ENTRY(fubyte)
1358: movl 4(%esp),%edx
1359: cmpl $VM_MAXUSER_ADDRESS-1,%edx
1360: ja _C_LABEL(fusuaddrfault)
1361: GET_CURPCB(%ecx)
1362: movl $_C_LABEL(fusufault),PCB_ONFAULT(%ecx)
1363: movzbl (%edx),%eax
1364: movl $0,PCB_ONFAULT(%ecx)
1365: ret
1366:
1367: /*
1368: * Handle faults from [fs]u*(). Clean up and return -1.
1369: */
1370: /* LINTSTUB: Ignore */
1371: NENTRY(fusufault)
1372: movl $0,PCB_ONFAULT(%ecx)
1373: movl $-1,%eax
1374: ret
1375:
1376: /*
1377: * Handle faults from [fs]u*(). Clean up and return -1. This differs from
1378: * fusufault() in that trap() will recognize it and return immediately rather
1379: * than trying to page fault.
1380: */
1381: /* LINTSTUB: Ignore */
1382: NENTRY(fusubail)
1383: movl $0,PCB_ONFAULT(%ecx)
1384: movl $-1,%eax
1385: ret
1386:
1387: /*
1388: * Handle earlier faults from [fs]u*(), due to our of range addresses.
1389: */
1390: /* LINTSTUB: Ignore */
1391: NENTRY(fusuaddrfault)
1392: movl $-1,%eax
1393: ret
1394:
1395: /*
1396: * int suword(void *uaddr, long x);
1397: * Store an int in the user's address space.
1398: * see suword(9)
1399: */
1400: /* LINTSTUB: Func: int suword(void *base, long c) */
1401: ENTRY(suword)
1402: movl 4(%esp),%edx
1403: cmpl $VM_MAXUSER_ADDRESS-4,%edx
1404: ja _C_LABEL(fusuaddrfault)
1405:
1406: #if defined(I386_CPU)
1407: #if defined(I486_CPU) || defined(I586_CPU) || defined(I686_CPU)
1408: cmpl $CPUCLASS_386,_C_LABEL(cpu_class)
1409: jne 2f
1410: #endif /* I486_CPU || I586_CPU || I686_CPU */
1411:
1412: GET_CURPCB(%eax)
1413: movl $3f,PCB_ONFAULT(%eax)
1414:
1415: movl %edx,%eax
1416: shrl $PGSHIFT,%eax # calculate pte address
1417: testb $PG_RW,_C_LABEL(PTmap)(,%eax,4)
1418: jnz 1f
1419:
1420: 3: /* Simulate a trap. */
1421: pushl %edx
1422: pushl %edx
1423: call _C_LABEL(trapwrite) # trapwrite(addr)
1424: addl $4,%esp # clear parameter from the stack
1425: popl %edx
1426: GET_CURPCB(%ecx)
1427: testl %eax,%eax
1428: jnz _C_LABEL(fusufault)
1429:
1430: 1: /* XXX also need to check the following 3 bytes for validity! */
1431: #endif
1432:
1433: 2: GET_CURPCB(%ecx)
1434: movl $_C_LABEL(fusufault),PCB_ONFAULT(%ecx)
1435:
1436: movl 8(%esp),%eax
1437: movl %eax,(%edx)
1438: xorl %eax,%eax
1439: movl %eax,PCB_ONFAULT(%ecx)
1440: ret
1441:
1442: /*
1443: * int susword(void *uaddr, short x);
1444: * Store a short in the user's address space.
1445: * see susword(9)
1446: */
1447: /* LINTSTUB: Func: int susword(void *base, short c) */
1448: ENTRY(susword)
1449: movl 4(%esp),%edx
1450: cmpl $VM_MAXUSER_ADDRESS-2,%edx
1451: ja _C_LABEL(fusuaddrfault)
1452:
1453: #if defined(I386_CPU)
1454: #if defined(I486_CPU) || defined(I586_CPU) || defined(I686_CPU)
1455: cmpl $CPUCLASS_386,_C_LABEL(cpu_class)
1456: jne 2f
1457: #endif /* I486_CPU || I586_CPU || I686_CPU */
1458:
1459: GET_CURPCB(%eax)
1460: movl $3f,PCB_ONFAULT(%eax)
1461:
1462: movl %edx,%eax
1463: shrl $PGSHIFT,%eax # calculate pte address
1464: testb $PG_RW,_C_LABEL(PTmap)(,%eax,4)
1465: jnz 1f
1466:
1467: 3: /* Simulate a trap. */
1468: pushl %edx
1469: pushl %edx
1470: call _C_LABEL(trapwrite) # trapwrite(addr)
1471: addl $4,%esp # clear parameter from the stack
1472: popl %edx
1473: GET_CURPCB(%ecx)
1474: testl %eax,%eax
1475: jnz _C_LABEL(fusufault)
1476:
1477: 1: /* XXX also need to check the following byte for validity! */
1478: #endif
1479:
1480: 2: GET_CURPCB(%ecx)
1481: movl $_C_LABEL(fusufault),PCB_ONFAULT(%ecx)
1482:
1483: movl 8(%esp),%eax
1484: movw %ax,(%edx)
1485: xorl %eax,%eax
1486: movl %eax,PCB_ONFAULT(%ecx)
1487: ret
1488:
1489: /*
1490: * int suswintr(void *uaddr, short x);
1491: * Store a short in the user's address space. Can be called during an
1492: * interrupt.
1493: * see suswintr(9)
1494: */
1495: /* LINTSTUB: Func: int suswintr(void *base, short c) */
1496: ENTRY(suswintr)
1497: movl 4(%esp),%edx
1498: cmpl $VM_MAXUSER_ADDRESS-2,%edx
1499: ja _C_LABEL(fusuaddrfault)
1.5 thorpej 1500: movl CPUVAR(CURLWP),%ecx
1501: movl L_ADDR(%ecx),%ecx
1.1 fvdl 1502: movl $_C_LABEL(fusubail),PCB_ONFAULT(%ecx)
1503:
1504: #if defined(I386_CPU)
1505: #if defined(I486_CPU) || defined(I586_CPU) || defined(I686_CPU)
1506: cmpl $CPUCLASS_386,_C_LABEL(cpu_class)
1507: jne 2f
1508: #endif /* I486_CPU || I586_CPU || I686_CPU */
1509:
1510: movl %edx,%eax
1511: shrl $PGSHIFT,%eax # calculate pte address
1512: testb $PG_RW,_C_LABEL(PTmap)(,%eax,4)
1513: jnz 1f
1514:
1515: /* Simulate a trap. */
1516: jmp _C_LABEL(fusubail)
1517:
1518: 1: /* XXX also need to check the following byte for validity! */
1519: #endif
1520:
1521: 2: movl 8(%esp),%eax
1522: movw %ax,(%edx)
1523: xorl %eax,%eax
1524: movl %eax,PCB_ONFAULT(%ecx)
1525: ret
1526:
1527: /*
1528: * int subyte(void *uaddr, char x);
1529: * Store a byte in the user's address space.
1530: * see subyte(9)
1531: */
1532: /* LINTSTUB: Func: int subyte(void *base, int c) */
1533: ENTRY(subyte)
1534: movl 4(%esp),%edx
1535: cmpl $VM_MAXUSER_ADDRESS-1,%edx
1536: ja _C_LABEL(fusuaddrfault)
1537:
1538: #if defined(I386_CPU)
1539: #if defined(I486_CPU) || defined(I586_CPU) || defined(I686_CPU)
1540: cmpl $CPUCLASS_386,_C_LABEL(cpu_class)
1541: jne 2f
1542: #endif /* I486_CPU || I586_CPU || I686_CPU */
1543:
1544: GET_CURPCB(%eax)
1545: movl $3f,PCB_ONFAULT(%eax)
1546:
1547: movl %edx,%eax
1548: shrl $PGSHIFT,%eax # calculate pte address
1549: testb $PG_RW,_C_LABEL(PTmap)(,%eax,4)
1550: jnz 1f
1551:
1552: 3: /* Simulate a trap. */
1553: pushl %edx
1554: pushl %edx
1555: call _C_LABEL(trapwrite) # trapwrite(addr)
1556: addl $4,%esp # clear parameter from the stack
1557: popl %edx
1558: GET_CURPCB(%ecx)
1559: testl %eax,%eax
1560: jnz _C_LABEL(fusufault)
1561:
1562: 1:
1563: #endif
1564:
1565: 2: GET_CURPCB(%ecx)
1566: movl $_C_LABEL(fusufault),PCB_ONFAULT(%ecx)
1567:
1568: movb 8(%esp),%al
1569: movb %al,(%edx)
1570: xorl %eax,%eax
1571: movl %eax,PCB_ONFAULT(%ecx)
1572: ret
1573:
1574: /*****************************************************************************/
1575:
1576: /*
1577: * The following is i386-specific nonsense.
1578: */
1579:
1580: /*
1581: * void lgdt(struct region_descriptor *rdp);
1582: * Load a new GDT pointer (and do any necessary cleanup).
1583: * XXX It's somewhat questionable whether reloading all the segment registers
1584: * is necessary, since the actual descriptor data is not changed except by
1585: * process creation and exit, both of which clean up via task switches. OTOH,
1586: * this only happens at run time when the GDT is resized.
1587: */
1588: /* LINTSTUB: Func: void lgdt(struct region_descriptor *rdp) */
1589: NENTRY(lgdt)
1590: /* Reload the descriptor table. */
1591: movl 4(%esp),%eax
1592: lgdt (%eax)
1593: /* Flush the prefetch queue. */
1594: jmp 1f
1595: nop
1596: 1: /* Reload "stale" selectors. */
1597: movl $GSEL(GDATA_SEL, SEL_KPL),%eax
1598: movw %ax,%ds
1599: movw %ax,%es
1600: movw %ax,%gs
1601: movw %ax,%ss
1602: movl $GSEL(GCPU_SEL, SEL_KPL),%eax
1603: movw %ax,%fs
1604: /* Reload code selector by doing intersegment return. */
1605: popl %eax
1606: pushl $GSEL(GCODE_SEL, SEL_KPL)
1607: pushl %eax
1608: lret
1609:
1610: /*****************************************************************************/
1611:
1612: /*
1613: * These functions are primarily used by DDB.
1614: */
1615:
1616: /* LINTSTUB: Func: int setjmp (label_t *l) */
1617: ENTRY(setjmp)
1618: movl 4(%esp),%eax
1619: movl %ebx,(%eax) # save ebx
1620: movl %esp,4(%eax) # save esp
1621: movl %ebp,8(%eax) # save ebp
1622: movl %esi,12(%eax) # save esi
1623: movl %edi,16(%eax) # save edi
1624: movl (%esp),%edx # get rta
1625: movl %edx,20(%eax) # save eip
1626: xorl %eax,%eax # return (0);
1627: ret
1628:
1629: /* LINTSTUB: Func: void longjmp (label_t *l) */
1630: ENTRY(longjmp)
1631: movl 4(%esp),%eax
1632: movl (%eax),%ebx # restore ebx
1633: movl 4(%eax),%esp # restore esp
1634: movl 8(%eax),%ebp # restore ebp
1635: movl 12(%eax),%esi # restore esi
1636: movl 16(%eax),%edi # restore edi
1637: movl 20(%eax),%edx # get rta
1638: movl %edx,(%esp) # put in return frame
1639: xorl %eax,%eax # return (1);
1640: incl %eax
1641: ret
1642:
1643: /*****************************************************************************/
1644:
1645: .globl _C_LABEL(sched_whichqs),_C_LABEL(sched_qs)
1646: .globl _C_LABEL(uvmexp),_C_LABEL(panic)
1647:
1648: #ifdef DIAGNOSTIC
1649: NENTRY(switch_error)
1650: pushl $1f
1651: call _C_LABEL(panic)
1652: /* NOTREACHED */
1653: 1: .asciz "cpu_switch"
1654: #endif /* DIAGNOSTIC */
1655:
1656: /*
1.5 thorpej 1657: * void cpu_switch(struct lwp *)
1.1 fvdl 1658: * Find a runnable process and switch to it. Wait if necessary. If the new
1659: * process is the same as the old one, we short-circuit the context save and
1660: * restore.
1661: *
1662: * Note that the stack frame layout is known to "struct switchframe"
1663: * in <machine/frame.h> and to the code in cpu_fork() which initializes
1.5 thorpej 1664: * it for a new lwp.
1.1 fvdl 1665: */
1666: ENTRY(cpu_switch)
1667: pushl %ebx
1668: pushl %esi
1669: pushl %edi
1670:
1671: #ifdef DEBUG
1672: cmpl $IPL_SCHED,CPUVAR(ILEVEL)
1673: jae 1f
1.5 thorpej 1674: pushl $2f
1.1 fvdl 1675: call _C_LABEL(panic)
1676: /* NOTREACHED */
1.5 thorpej 1677: 2: .asciz "not splsched() in cpu_switch!"
1.1 fvdl 1678: 1:
1679: #endif /* DEBUG */
1680:
1.5 thorpej 1681: movl 16(%esp),%esi # current
1.1 fvdl 1682:
1683: /*
1.5 thorpej 1684: * Clear curlwp so that we don't accumulate system time while idle.
1685: * This also insures that schedcpu() will move the old lwp to
1.1 fvdl 1686: * the correct queue if it happens to get called from the spllower()
1687: * below and changes the priority. (See corresponding comment in
1688: * userret()).
1689: */
1.5 thorpej 1690: movl $0,CPUVAR(CURLWP)
1.1 fvdl 1691: /*
1.5 thorpej 1692: * First phase: find new lwp.
1.1 fvdl 1693: *
1694: * Registers:
1695: * %eax - queue head, scratch, then zero
1696: * %ebx - queue number
1697: * %ecx - cached value of whichqs
1.5 thorpej 1698: * %edx - next lwp in queue
1699: * %esi - old lwp
1700: * %edi - new lwp
1.1 fvdl 1701: */
1702:
1.5 thorpej 1703: /* Look for new lwp. */
1.1 fvdl 1704: cli # splhigh doesn't do a cli
1705: movl _C_LABEL(sched_whichqs),%ecx
1706: bsfl %ecx,%ebx # find a full q
1707: jnz switch_dequeue
1708:
1709: /*
1710: * idling: save old context.
1711: *
1712: * Registers:
1713: * %eax, %ecx - scratch
1.5 thorpej 1714: * %esi - old lwp, then old pcb
1.1 fvdl 1715: * %edi - idle pcb
1716: */
1717:
1718: pushl %esi
1719: call _C_LABEL(pmap_deactivate) # pmap_deactivate(oldproc)
1720: addl $4,%esp
1721:
1.5 thorpej 1722: movl L_ADDR(%esi),%esi
1.1 fvdl 1723:
1724: /* Save stack pointers. */
1725: movl %esp,PCB_ESP(%esi)
1726: movl %ebp,PCB_EBP(%esi)
1727:
1728: /* Find idle PCB for this CPU */
1729: #ifndef MULTIPROCESSOR
1.5 thorpej 1730: movl $_C_LABEL(lwp0),%ebx
1731: movl L_ADDR(%ebx),%edi
1732: movl L_MD_TSS_SEL(%ebx),%edx
1.1 fvdl 1733: #else
1734: movl CPUVAR(IDLE_PCB),%edi
1735: movl CPUVAR(IDLE_TSS_SEL),%edx
1736: #endif
1.5 thorpej 1737: movl $0,CPUVAR(CURLWP) /* In case we fault... */
1.1 fvdl 1738:
1739: /* Restore the idle context (avoid interrupts) */
1740: cli
1741:
1742: /* Restore stack pointers. */
1743: movl PCB_ESP(%edi),%esp
1744: movl PCB_EBP(%edi),%ebp
1745:
1746:
1747: /* Switch address space. */
1748: movl PCB_CR3(%edi),%ecx
1749: movl %ecx,%cr3
1750:
1751: /* Switch TSS. Reset "task busy" flag before loading. */
1752: #ifdef MULTIPROCESSOR
1753: movl CPUVAR(GDT),%eax
1754: #else
1755: movl _C_LABEL(gdt),%eax
1756: #endif
1757: andl $~0x0200,4-SEL_KPL(%eax,%edx,1)
1758: ltr %dx
1759:
1760: /* We're always in the kernel, so we don't need the LDT. */
1761:
1762: /* Restore cr0 (including FPU state). */
1763: movl PCB_CR0(%edi),%ecx
1764: movl %ecx,%cr0
1765:
1766: /* Record new pcb. */
1767: SET_CURPCB(%edi)
1768:
1769: xorl %esi,%esi
1770: sti
1771: idle_unlock:
1772: #if defined(MULTIPROCESSOR) || defined(LOCKDEBUG)
1773: call _C_LABEL(sched_unlock_idle)
1774: #endif
1775: /* Interrupts are okay again. */
1.2 fvdl 1776: pushl $IPL_NONE # spl0()
1.1 fvdl 1777: call _C_LABEL(Xspllower) # process pending interrupts
1.2 fvdl 1778: addl $4,%esp
1.1 fvdl 1779: jmp idle_start
1780: idle_zero:
1781: sti
1782: call _C_LABEL(uvm_pageidlezero)
1783: cli
1784: cmpl $0,_C_LABEL(sched_whichqs)
1785: jnz idle_exit
1786: idle_loop:
1787: /* Try to zero some pages. */
1788: movl _C_LABEL(uvm)+UVM_PAGE_IDLE_ZERO,%ecx
1789: testl %ecx,%ecx
1790: jnz idle_zero
1791: sti
1792: hlt
1793: NENTRY(mpidle)
1794: idle_start:
1795: cli
1796: cmpl $0,_C_LABEL(sched_whichqs)
1797: jz idle_loop
1798: idle_exit:
1799: movl $IPL_HIGH,CPUVAR(ILEVEL) # splhigh
1.14 fvdl 1800: sti
1.1 fvdl 1801: #if defined(MULTIPROCESSOR) || defined(LOCKDEBUG)
1802: call _C_LABEL(sched_lock_idle)
1803: #endif
1804: movl _C_LABEL(sched_whichqs),%ecx
1805: bsfl %ecx,%ebx
1806: jz idle_unlock
1807:
1808: switch_dequeue:
1809: /*
1810: * we're running at splhigh(), but it's otherwise okay to take
1811: * interrupts here.
1812: */
1813: sti
1814: leal _C_LABEL(sched_qs)(,%ebx,8),%eax # select q
1815:
1.5 thorpej 1816: movl L_FORW(%eax),%edi # unlink from front of process q
1.1 fvdl 1817: #ifdef DIAGNOSTIC
1818: cmpl %edi,%eax # linked to self (i.e. nothing queued)?
1819: je _C_LABEL(switch_error) # not possible
1820: #endif /* DIAGNOSTIC */
1.5 thorpej 1821: movl L_FORW(%edi),%edx
1822: movl %edx,L_FORW(%eax)
1823: movl %eax,L_BACK(%edx)
1.1 fvdl 1824:
1825: cmpl %edx,%eax # q empty?
1826: jne 3f
1827:
1828: btrl %ebx,%ecx # yes, clear to indicate empty
1829: movl %ecx,_C_LABEL(sched_whichqs) # update q status
1830:
1831: 3: /* We just did it. */
1832: xorl %eax,%eax
1833: CLEAR_RESCHED(%eax)
1834:
1.5 thorpej 1835: switch_resume:
1.1 fvdl 1836: #ifdef DIAGNOSTIC
1.5 thorpej 1837: cmpl %eax,L_WCHAN(%edi) # Waiting for something?
1.1 fvdl 1838: jne _C_LABEL(switch_error) # Yes; shouldn't be queued.
1.5 thorpej 1839: cmpb $LSRUN,L_STAT(%edi) # In run state?
1.1 fvdl 1840: jne _C_LABEL(switch_error) # No; shouldn't be queued.
1841: #endif /* DIAGNOSTIC */
1842:
1.5 thorpej 1843: /* Isolate lwp. XXX Is this necessary? */
1844: movl %eax,L_BACK(%edi)
1.1 fvdl 1845:
1.5 thorpej 1846: /* Record new lwp. */
1847: movb $LSONPROC,L_STAT(%edi) # l->l_stat = LSONPROC
1848: SET_CURLWP(%edi,%ecx)
1.1 fvdl 1849:
1.5 thorpej 1850: /* Skip context switch if same lwp. */
1.10 fvdl 1851: xorl %ebx,%ebx
1.1 fvdl 1852: cmpl %edi,%esi
1853: je switch_return
1854:
1.5 thorpej 1855: /* If old lwp exited, don't bother. */
1.1 fvdl 1856: testl %esi,%esi
1857: jz switch_exited
1858:
1859: /*
1860: * Second phase: save old context.
1861: *
1862: * Registers:
1863: * %eax, %ecx - scratch
1.5 thorpej 1864: * %esi - old lwp, then old pcb
1865: * %edi - new lwp
1.1 fvdl 1866: */
1867:
1868: pushl %esi
1869: call _C_LABEL(pmap_deactivate) # pmap_deactivate(oldproc)
1870: addl $4,%esp
1871:
1.5 thorpej 1872: movl L_ADDR(%esi),%esi
1.1 fvdl 1873:
1874: /* Save stack pointers. */
1875: movl %esp,PCB_ESP(%esi)
1876: movl %ebp,PCB_EBP(%esi)
1877:
1878: switch_exited:
1879: /*
1880: * Third phase: restore saved context.
1881: *
1882: * Registers:
1883: * %eax, %ebx, %ecx, %edx - scratch
1884: * %esi - new pcb
1.5 thorpej 1885: * %edi - new lwp
1.1 fvdl 1886: */
1887:
1888: /* No interrupts while loading new state. */
1889: cli
1.5 thorpej 1890: movl L_ADDR(%edi),%esi
1.1 fvdl 1891:
1892: /* Restore stack pointers. */
1893: movl PCB_ESP(%esi),%esp
1894: movl PCB_EBP(%esi),%ebp
1895:
1896: #if 0
1897: /* Don't bother with the rest if switching to a system process. */
1.5 thorpej 1898: testl $P_SYSTEM,L_FLAG(%edi); XXX NJWLWP lwp's don't have P_SYSTEM!
1.1 fvdl 1899: jnz switch_restored
1900: #endif
1901:
1902: #ifdef MULTIPROCESSOR
1903: movl CPUVAR(GDT),%eax
1904: #else
1905: /* Load TSS info. */
1906: movl _C_LABEL(gdt),%eax
1907: #endif
1.5 thorpej 1908: movl L_MD_TSS_SEL(%edi),%edx
1.1 fvdl 1909:
1910: /* Switch TSS. Reset "task busy" flag before loading. */
1911: andl $~0x0200,4(%eax,%edx, 1)
1912: ltr %dx
1913:
1914: pushl %edi
1915: call _C_LABEL(pmap_activate) # pmap_activate(p)
1916: addl $4,%esp
1917:
1918: #if 0
1919: switch_restored:
1920: #endif
1921: /* Restore cr0 (including FPU state). */
1922: movl PCB_CR0(%esi),%ecx
1923: #ifdef MULTIPROCESSOR
1924: /*
1925: * If our floating point registers are on a different cpu,
1926: * clear CR0_TS so we'll trap rather than reuse bogus state.
1927: */
1928: movl PCB_FPCPU(%esi),%ebx
1929: cmpl CPUVAR(SELF),%ebx
1930: jz 1f
1931: orl $CR0_TS,%ecx
1932: 1:
1933: #endif
1934: movl %ecx,%cr0
1935:
1936: /* Record new pcb. */
1937: SET_CURPCB(%esi)
1938:
1939: /* Interrupts are okay again. */
1940: sti
1941:
1942: /*
1943: * Check for restartable atomic sequences (RAS)
1944: */
1.5 thorpej 1945: movl CPUVAR(CURLWP),%edi
1946: movl L_PROC(%edi),%esi
1947: cmpl $0,P_NRAS(%esi)
1.1 fvdl 1948: je 1f
1.5 thorpej 1949: movl L_MD_REGS(%edi),%ebx
1.4 gmcgarry 1950: movl TF_EIP(%ebx),%eax
1.1 fvdl 1951: pushl %eax
1.5 thorpej 1952: pushl %esi
1.1 fvdl 1953: call _C_LABEL(ras_lookup)
1954: addl $8,%esp
1955: cmpl $-1,%eax
1956: je 1f
1.4 gmcgarry 1957: movl %eax,TF_EIP(%ebx)
1.1 fvdl 1958: 1:
1.10 fvdl 1959: movl $1,%ebx
1.1 fvdl 1960:
1961: switch_return:
1962: #if defined(MULTIPROCESSOR) || defined(LOCKDEBUG)
1963: call _C_LABEL(sched_unlock_idle)
1964: #endif
1.2 fvdl 1965: pushl $IPL_NONE # spl0()
1.1 fvdl 1966: call _C_LABEL(Xspllower) # process pending interrupts
1.2 fvdl 1967: addl $4,%esp
1.1 fvdl 1968: movl $IPL_HIGH,CPUVAR(ILEVEL) # splhigh()
1.9 fvdl 1969:
1970: movl %ebx,%eax
1.1 fvdl 1971:
1972: popl %edi
1973: popl %esi
1974: popl %ebx
1975: ret
1976:
1977: /*
1.5 thorpej 1978: * void cpu_switchto(struct lwp *current, struct lwp *next)
1979: * Switch to the specified next LWP.
1980: */
1981: ENTRY(cpu_switchto)
1982: pushl %ebx
1983: pushl %esi
1984: pushl %edi
1985:
1986: #ifdef DEBUG
1987: cmpl $IPL_SCHED,CPUVAR(ILEVEL)
1988: jae 1f
1989: pushl $2f
1990: call _C_LABEL(panic)
1991: /* NOTREACHED */
1992: 2: .asciz "not splsched() in cpu_switchto!"
1993: 1:
1994: #endif /* DEBUG */
1995:
1996: movl 16(%esp),%esi # current
1997: movl 20(%esp),%edi # next
1998:
1999: /*
2000: * Clear curlwp so that we don't accumulate system time while idle.
2001: * This also insures that schedcpu() will move the old process to
2002: * the correct queue if it happens to get called from the spllower()
2003: * below and changes the priority. (See corresponding comment in
2004: * usrret()).
2005: *
2006: * XXX Is this necessary? We know we won't go idle.
2007: */
2008: movl $0,CPUVAR(CURLWP)
2009:
2010: /*
2011: * We're running at splhigh(), but it's otherwise okay to take
2012: * interrupts here.
2013: */
2014: sti
2015:
2016: /* Jump into the middle of cpu_switch */
2017: xorl %eax,%eax
2018: jmp switch_resume
2019:
2020: /*
2021: * void switch_exit(struct lwp *l, void (*exit)(struct lwp *));
2022: * Switch to the appropriate idle context (lwp0's if uniprocessor; the cpu's
1.1 fvdl 2023: * if multiprocessor) and deallocate the address space and kernel stack for p.
2024: * Then jump into cpu_switch(), as if we were in the idle proc all along.
2025: */
2026: #ifndef MULTIPROCESSOR
1.5 thorpej 2027: .globl _C_LABEL(lwp0)
1.1 fvdl 2028: #endif
2029: .globl _C_LABEL(uvmspace_free),_C_LABEL(kernel_map)
2030: .globl _C_LABEL(uvm_km_free),_C_LABEL(tss_free)
1.6 drochner 2031: /* LINTSTUB: Func: void switch_exit(struct lwp *l, void (*exit)(struct lwp *)) */
1.1 fvdl 2032: ENTRY(switch_exit)
2033: movl 4(%esp),%edi # old process
1.5 thorpej 2034: movl 8(%esp),%eax # exit func
1.1 fvdl 2035: #ifndef MULTIPROCESSOR
1.5 thorpej 2036: movl $_C_LABEL(lwp0),%ebx
2037: movl L_ADDR(%ebx),%esi
2038: movl L_MD_TSS_SEL(%ebx),%edx
1.1 fvdl 2039: #else
2040: movl CPUVAR(IDLE_PCB),%esi
2041: movl CPUVAR(IDLE_TSS_SEL),%edx
2042: #endif
2043: /* In case we fault... */
1.5 thorpej 2044: movl $0,CPUVAR(CURLWP)
1.1 fvdl 2045:
2046: /* Restore the idle context. */
2047: cli
2048:
2049: /* Restore stack pointers. */
2050: movl PCB_ESP(%esi),%esp
2051: movl PCB_EBP(%esi),%ebp
2052:
1.5 thorpej 2053: /* Save exit func. */
2054: pushl %eax
2055:
1.1 fvdl 2056: /* Load TSS info. */
2057: #ifdef MULTIPROCESSOR
2058: movl CPUVAR(GDT),%eax
2059: #else
2060: /* Load TSS info. */
2061: movl _C_LABEL(gdt),%eax
2062: #endif
2063:
2064: /* Switch address space. */
2065: movl PCB_CR3(%esi),%ecx
2066: movl %ecx,%cr3
2067:
2068: /* Switch TSS. */
2069: andl $~0x0200,4-SEL_KPL(%eax,%edx,1)
2070: ltr %dx
2071:
2072: /* We're always in the kernel, so we don't need the LDT. */
2073:
2074: /* Restore cr0 (including FPU state). */
2075: movl PCB_CR0(%esi),%ecx
2076: movl %ecx,%cr0
2077:
2078: /* Record new pcb. */
2079: SET_CURPCB(%esi)
2080:
2081: /* Interrupts are okay again. */
2082: sti
2083:
2084: /*
2085: * Schedule the dead process's vmspace and stack to be freed.
2086: */
1.5 thorpej 2087: movl 0(%esp),%eax /* %eax = exit func */
2088: movl %edi,0(%esp) /* {lwp_}exit2(l) */
2089: call *%eax
1.1 fvdl 2090: addl $4,%esp
2091:
2092: /* Jump into cpu_switch() with the right state. */
2093: xorl %esi,%esi
1.5 thorpej 2094: movl %esi,CPUVAR(CURLWP)
1.1 fvdl 2095: jmp idle_start
2096:
2097: /*
2098: * void savectx(struct pcb *pcb);
2099: * Update pcb, saving current processor state.
2100: */
2101: /* LINTSTUB: Func: void savectx(struct pcb *pcb) */
2102: ENTRY(savectx)
2103: movl 4(%esp),%edx # edx = p->p_addr
2104:
2105: /* Save stack pointers. */
2106: movl %esp,PCB_ESP(%edx)
2107: movl %ebp,PCB_EBP(%edx)
2108:
2109: ret
2110:
2111: /*
2112: * Old call gate entry for syscall
2113: */
2114: /* LINTSTUB: Var: char Xosyscall[1]; */
2115: IDTVEC(osyscall)
2116: /* Set eflags in trap frame. */
2117: pushfl
2118: popl 8(%esp)
2119: pushl $7 # size of instruction for restart
2120: jmp syscall1
2121:
2122: /*
2123: * Trap gate entry for syscall
2124: */
2125: /* LINTSTUB: Var: char Xsyscall[1]; */
2126: IDTVEC(syscall)
2127: pushl $2 # size of instruction for restart
2128: syscall1:
2129: pushl $T_ASTFLT # trap # for doing ASTs
2130: INTRENTRY
2131:
2132: #ifdef DIAGNOSTIC
2133: movl CPUVAR(ILEVEL),%ebx
2134: testl %ebx,%ebx
2135: jz 1f
2136: pushl $5f
2137: call _C_LABEL(printf)
2138: addl $4,%esp
2139: #ifdef DDB
2140: int $3
2141: #endif
2142: 1:
2143: #endif /* DIAGNOSTIC */
1.5 thorpej 2144: movl CPUVAR(CURLWP),%edx
2145: movl %esp,L_MD_REGS(%edx) # save pointer to frame
2146: movl L_PROC(%edx),%edx
1.15 fvdl 2147: pushl %esp
1.1 fvdl 2148: call *P_MD_SYSCALL(%edx) # get pointer to syscall() function
1.15 fvdl 2149: addl $4,%esp
1.1 fvdl 2150: 2: /* Check for ASTs on exit to user mode. */
2151: cli
1.5 thorpej 2152: CHECK_ASTPENDING(%eax)
1.1 fvdl 2153: je 1f
2154: /* Always returning to user mode here. */
1.5 thorpej 2155: CLEAR_ASTPENDING(%eax)
1.1 fvdl 2156: sti
2157: /* Pushed T_ASTFLT into tf_trapno on entry. */
1.15 fvdl 2158: pushl %esp
1.1 fvdl 2159: call _C_LABEL(trap)
1.15 fvdl 2160: addl $4,%esp
1.1 fvdl 2161: jmp 2b
2162: #ifndef DIAGNOSTIC
2163: 1: INTRFASTEXIT
2164: #else /* DIAGNOSTIC */
2165: 1: cmpl $IPL_NONE,CPUVAR(ILEVEL)
2166: jne 3f
2167: INTRFASTEXIT
2168: 3: sti
2169: pushl $4f
2170: call _C_LABEL(printf)
2171: addl $4,%esp
2172: #ifdef DDB
2173: int $3
2174: #endif /* DDB */
2175: movl $IPL_NONE,CPUVAR(ILEVEL)
2176: jmp 2b
2177: 4: .asciz "WARNING: SPL NOT LOWERED ON SYSCALL EXIT\n"
2178: 5: .asciz "WARNING: SPL NOT ZERO ON SYSCALL ENTRY\n"
2179: #endif /* DIAGNOSTIC */
2180:
2181: #if NNPX > 0
2182: /*
2183: * Special interrupt handlers. Someday intr0-intr15 will be used to count
2184: * interrupts. We'll still need a special exception 16 handler. The busy
2185: * latch stuff in probintr() can be moved to npxprobe().
2186: */
2187:
2188: /* LINTSTUB: Func: void probeintr(void) */
2189: NENTRY(probeintr)
2190: ss
2191: incl _C_LABEL(npx_intrs_while_probing)
2192: pushl %eax
2193: movb $0x20,%al # EOI (asm in strings loses cpp features)
2194: outb %al,$0xa0 # IO_ICU2
2195: outb %al,$0x20 # IO_ICU1
2196: movb $0,%al
2197: outb %al,$0xf0 # clear BUSY# latch
2198: popl %eax
2199: iret
2200:
2201: /* LINTSTUB: Func: void probetrap(void) */
2202: NENTRY(probetrap)
2203: ss
2204: incl _C_LABEL(npx_traps_while_probing)
2205: fnclex
2206: iret
2207:
2208: /* LINTSTUB: Func: int npx586bug1(int a, int b) */
2209: NENTRY(npx586bug1)
2210: fildl 4(%esp) # x
2211: fildl 8(%esp) # y
2212: fld %st(1)
2213: fdiv %st(1),%st # x/y
2214: fmulp %st,%st(1) # (x/y)*y
2215: fsubrp %st,%st(1) # x-(x/y)*y
2216: pushl $0
2217: fistpl (%esp)
2218: popl %eax
2219: ret
2220: #endif /* NNPX > 0 */
CVSweb <webmaster@jp.NetBSD.org>