[BACK]Return to SYS.h CVS log [TXT][DIR] Up to [cvs.NetBSD.org] / src / lib / libc / arch / powerpc64

File: [cvs.NetBSD.org] / src / lib / libc / arch / powerpc64 / SYS.h (download)

Revision 1.4, Mon Jan 12 02:48:20 2015 UTC (7 years, 8 months ago) by dennis
Branch: MAIN
CVS Tags: prg-localcount2-base3, prg-localcount2-base2, prg-localcount2-base1, prg-localcount2-base, prg-localcount2, phil-wifi-base, phil-wifi-20200421, phil-wifi-20200411, phil-wifi-20200406, phil-wifi-20191119, phil-wifi-20190609, phil-wifi, pgoyette-localcount-base, pgoyette-localcount-20170426, pgoyette-localcount-20170320, pgoyette-localcount-20170107, pgoyette-localcount-20161104, pgoyette-localcount-20160806, pgoyette-localcount-20160726, pgoyette-localcount, pgoyette-compat-merge-20190127, pgoyette-compat-base, pgoyette-compat-20190127, pgoyette-compat-20190118, pgoyette-compat-1226, pgoyette-compat-1126, pgoyette-compat-1020, pgoyette-compat-0930, pgoyette-compat-0906, pgoyette-compat-0728, pgoyette-compat-0625, pgoyette-compat-0521, pgoyette-compat-0502, pgoyette-compat-0422, pgoyette-compat-0415, pgoyette-compat-0407, pgoyette-compat-0330, pgoyette-compat-0322, pgoyette-compat-0315, pgoyette-compat, perseant-stdc-iso10646-base, perseant-stdc-iso10646, netbsd-9-base, netbsd-9-3-RELEASE, netbsd-9-2-RELEASE, netbsd-9-1-RELEASE, netbsd-9-0-RELEASE, netbsd-9-0-RC2, netbsd-9-0-RC1, netbsd-9, netbsd-8-base, netbsd-8-2-RELEASE, netbsd-8-1-RELEASE, netbsd-8-1-RC1, netbsd-8-0-RELEASE, netbsd-8-0-RC2, netbsd-8-0-RC1, netbsd-8, matt-nb8-mediatek-base, matt-nb8-mediatek, localcount-20160914, is-mlppp-base, is-mlppp, cjep_sun2x-base1, cjep_sun2x-base, cjep_sun2x, cjep_staticlib_x-base1, cjep_staticlib_x-base, cjep_staticlib_x, bouyer-socketcan-base1, bouyer-socketcan-base, bouyer-socketcan, HEAD
Changes since 1.3: +34 -8 lines

Replace the branch to __cerror() in powerpc64 syscall stubs
with inline code which does what __cerror() was doing.  #ifdef
that code (i.e. all code) out of cerror.S; __cerror() is no more.
This seems to be necessary to fix the link of rescue/rescue, and
should have the pleasant side effect of making all other workarounds
done to keep the 'b __cerror' working unnecessary.

/*	$NetBSD: SYS.h,v 1.4 2015/01/12 02:48:20 dennis Exp $	*/

#include <machine/asm.h>
#include <sys/syscall.h>

/*
 * Inline what __cerror() is generally used to do since branching
 * to __cerror() can't be done reliably with the powerpc64 ABI.
 */
#ifdef _REENTRANT
#define	_DO_CERROR_SF_SZ	(SF_SZ + SF_ALIGN(8))
#define	_DO_CERROR()		mflr	%r0				;\
				streg	%r31,-8(%r1)			;\
				streg	%r0,SF_LR(%r1)			;\
				stptru	%r1,-_DO_CERROR_SF_SZ(%r1)	;\
				mr	%r31,%r3			;\
				bl	PIC_PLT(_C_LABEL(__errno))	;\
				nop					;\
				stint	%r31,0(%r3)			;\
				addi	%r1,%r1,_DO_CERROR_SF_SZ	;\
				ldreg	%r0,SF_LR(%r1)			;\
				ldreg	%r31,-8(%r1)			;\
				mtlr	%r0				;\
				li	%r3,-1				;\
				li	%r4,-1				;\
				blr
#else	/* !_REENTRANT */
#define	_DO_CERROR()		lwz	%r4,_C_LABEL(errno)@got(%r2)	;\
				stw	%r3,0(%r4)			;\
				li	%r3,-1				;\
				li	%r4,-1				;\
				blr
#endif	/* _REENTRANT */

/* Clearly BRANCH_TO_CERROR() no longer does that... */
#define	BRANCH_TO_CERROR()	_DO_CERROR()

#define	_DOSYSCALL(x)		li	%r0,(SYS_ ## x)		;\
				sc

#define	_SYSCALL_NOERROR(x,y)	.text				;\
				.p2align 2			;\
			ENTRY(x)				;\
				_DOSYSCALL(y)

#define _SYSCALL(x,y)		.text				;\
				.p2align 2			;\
			2:	_DO_CERROR()			;\
				_SYSCALL_NOERROR(x,y)		;\
				bso	2b

#define SYSCALL_NOERROR(x)	_SYSCALL_NOERROR(x,x)

#define SYSCALL(x)		_SYSCALL(x,x)

#define PSEUDO_NOERROR(x,y)	_SYSCALL_NOERROR(x,y)		;\
				blr				;\
				END(x)

#define PSEUDO(x,y)		_SYSCALL_NOERROR(x,y)		;\
				bnslr				;\
				_DO_CERROR()			;\
				END(x)

#define RSYSCALL_NOERROR(x)	PSEUDO_NOERROR(x,x)

#define RSYSCALL(x)		PSEUDO(x,x)

#define	WSYSCALL(weak,strong)	WEAK_ALIAS(weak,strong)		;\
				PSEUDO(strong,weak)