[BACK]Return to memccpy.S CVS log [TXT][DIR] Up to [cvs.NetBSD.org] / src / lib / libc / arch / m68k / string

File: [cvs.NetBSD.org] / src / lib / libc / arch / m68k / string / memccpy.S (download)

Revision 1.5, Tue Mar 18 18:20:37 2014 UTC (8 years, 6 months ago) by riastradh
Branch: MAIN
CVS Tags: yamt-pagecache-base9, tls-maxphys-base, tls-earlyentropy-base, tls-earlyentropy, riastradh-xf86-video-intel-2-7-1-pre-2-21-15, prg-localcount2-base3, prg-localcount2-base2, prg-localcount2-base1, prg-localcount2-base, prg-localcount2, phil-wifi-base, phil-wifi-20200421, phil-wifi-20200411, phil-wifi-20200406, phil-wifi-20191119, phil-wifi-20190609, phil-wifi, pgoyette-localcount-base, pgoyette-localcount-20170426, pgoyette-localcount-20170320, pgoyette-localcount-20170107, pgoyette-localcount-20161104, pgoyette-localcount-20160806, pgoyette-localcount-20160726, pgoyette-localcount, pgoyette-compat-merge-20190127, pgoyette-compat-base, pgoyette-compat-20190127, pgoyette-compat-20190118, pgoyette-compat-1226, pgoyette-compat-1126, pgoyette-compat-1020, pgoyette-compat-0930, pgoyette-compat-0906, pgoyette-compat-0728, pgoyette-compat-0625, pgoyette-compat-0521, pgoyette-compat-0502, pgoyette-compat-0422, pgoyette-compat-0415, pgoyette-compat-0407, pgoyette-compat-0330, pgoyette-compat-0322, pgoyette-compat-0315, pgoyette-compat, perseant-stdc-iso10646-base, perseant-stdc-iso10646, netbsd-9-base, netbsd-9-3-RELEASE, netbsd-9-2-RELEASE, netbsd-9-1-RELEASE, netbsd-9-0-RELEASE, netbsd-9-0-RC2, netbsd-9-0-RC1, netbsd-9, netbsd-8-base, netbsd-8-2-RELEASE, netbsd-8-1-RELEASE, netbsd-8-1-RC1, netbsd-8-0-RELEASE, netbsd-8-0-RC2, netbsd-8-0-RC1, netbsd-8, netbsd-7-nhusb-base-20170116, netbsd-7-nhusb-base, netbsd-7-nhusb, netbsd-7-base, netbsd-7-2-RELEASE, netbsd-7-1-RELEASE, netbsd-7-1-RC2, netbsd-7-1-RC1, netbsd-7-1-2-RELEASE, netbsd-7-1-1-RELEASE, netbsd-7-1, netbsd-7-0-RELEASE, netbsd-7-0-RC3, netbsd-7-0-RC2, netbsd-7-0-RC1, netbsd-7-0-2-RELEASE, netbsd-7-0-1-RELEASE, netbsd-7-0, netbsd-7, matt-nb8-mediatek-base, matt-nb8-mediatek, localcount-20160914, is-mlppp-base, is-mlppp, cjep_sun2x-base1, cjep_sun2x-base, cjep_sun2x, cjep_staticlib_x-base1, cjep_staticlib_x-base, cjep_staticlib_x, bouyer-socketcan-base1, bouyer-socketcan-base, bouyer-socketcan, HEAD
Changes since 1.4: +2 -2 lines

Merge riastradh-drm2 to HEAD.

/*	$NetBSD: memccpy.S,v 1.5 2014/03/18 18:20:37 riastradh Exp $	*/

/*
 * Copyright (C) 1999 Scott Reynolds.  All rights reserved.
 *
 * Redistribution and use in source and binary forms, with or without
 * modification, are permitted provided that the following conditions
 * are met:
 * 1. Redistributions of source code must retain the above copyright
 *    notice, this list of conditions and the following disclaimer.
 * 2. Redistributions in binary form must reproduce the above copyright
 *    notice, this list of conditions and the following disclaimer in the
 *    documentation and/or other materials provided with the distribution.
 * 3. The name of the author may not be used to endorse or promote products
 *    derived from this software without specific prior written permission.
 *
 * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
 * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
 * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
 * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
 * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
 * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
 * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
 * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
 * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
 * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
 */

#include <machine/asm.h>

#if defined(LIBC_SCCS) && !defined(lint)
	RCSID("$NetBSD: memccpy.S,v 1.5 2014/03/18 18:20:37 riastradh Exp $")
#endif /* LIBC_SCCS and not lint */

ENTRY(memccpy)
	movl	16(%sp),%d0		| count
	jeq	Lmcbail			| nothing to do

	movl	4(%sp),%a0		| a0 = toaddr
#ifndef __mcoldfire__
	subql	#1,%d0			|   prepare count for DBcc loop
#endif
	movl	8(%sp),%a1		| a1 = fromaddr
	movl	12(%sp),%d1		| d1 = terminator
	jeq	Lmcloop			|   handle ASCII NUL specially

	movl	%d2,-(%sp)		| save scratch register
Lmcnzloop:
	movb	(%a1)+,%d2		| move a byte
	movb	%d2,(%a0)+
	cmpb	%d2,%d1			| found the terminator?
#ifndef __mcoldfire__
	dbeq	%d0,Lmcnzloop		| if not, keep transferring,
#endif
	jeq	Lmcnzdone		|   otherwise done
#ifdef __mcoldfire__
	subql	#1,%d0
	jne	Lmcnzloop
#else
	clrw	%d0			| check to see if more to do
	subql	#1,%d0
	jcc	Lmcnzloop		| yes, keep going...
#endif

	movl	(%sp)+,%d2		| restore scratch register
	movql	#0,%d0			| no terminator found, return NULL
#ifdef __SVR4_ABI__
	movl	%d0,%a0			| XXX maybe use lea to avoid stall?
#endif
	rts

Lmcloop:
	movb	(%a1)+,(%a0)+		| move a byte; was it NUL?
#ifndef __mcoldfire__
	dbeq	%d0,Lmcloop		| if not, keep transferring,
#endif
	jeq	Lmcdone			|   otherwise done
#ifdef __mcoldfire__
	subql	#1,%d0
	jne	Lmcloop
#else
	clrw	%d0			| check to see if more to do
	subql	#1,%d0
	jcc	Lmcloop			| yes, keep going...
#endif
					| Note: %d0 is now -1!
	movql	#0,%d0			| no terminator found, return NULL
Lmcbail:
#ifdef __SVR4_ABI__
	movl	%d0,%a0			| XXX maybe use lea to avoid stall?
#endif
	rts

Lmcnzdone:
	movl	(%sp)+,%d2		| restore scratch register
Lmcdone:
	movl	%a0,%d0
	rts
END(memccpy)